Wtyczka Dialer

Ten dokument zgodny jest z NSIS 3.1


1. Wprowadzenie

Wtyczka dialer dla NSIS udostępnia pięć funkcji związanych z połączeniem z internetem.

Aby pobrać pliki z internetu, użyj wtyczki NSISdl.

2. Sposób użycia


Przykład:

ClearErrors                           ; Czyści flagę błędu
Dialer::NazwaFunkcji          ; Wywołuje funkcje Dialera
IfErrors "" +3                        ; Sprawdza błędy
  MessageBox MB_OK "Funkcja niedostępna"
  Quit
Pop $R0                                 ; Pobiera zwracaną wartość ze stosu
MessageBox MB_OK $R0       ; Wyświetla zwracaną wartość

Przykładowa funkcja


 ; ConnectInternet (używa wtyczki Dialer)
 ; Napisał Joost Verburg
 ;
 ; Funkcja ta próbuje utworzyć połączenie z internetem, jeśli nie jest dostępne żadne połączenie.
 ; Jeśli nie jesteś pewien czy system, na którym uruchomiono instalatora ma aktywne połączenie
 ; z internetem, wywołaj tę funkcję przed pobieraniem plików przez wtyczkę NSISdl.
 ;
 ; Funkcja wymaga Internet Explorera 3, lecz pyta o ręczne połączenie, jeśli nie jest on zainstalowany.

 Function ConnectInternet

   Push $R0

     ClearErrors
     Dialer::AttemptConnect
     IfErrors noie3

     Pop $R0
     StrCmp $R0 "online" connected
       MessageBox MB_OK|MB_ICONSTOP "Błąd połączenia z internetem."
       Quit ; Usuń, aby błędy nie były fatalne

     noie3:

     ; IE3 nie zainstalowany
     MessageBox MB_OK|MB_ICONINFORMATION "Proszę, połącz się teraz z internetem."

     connected:

   Pop $R0

 FunctionEnd

3. Funkcje

Jeśli dana funkcja nie jest dostepna w systemie, ustawiona zostanie flaga błędu.


3.1 AttemptConnect


Próbuje podłączyć system do internetu, jeśli jeszcze nie jest.

  • online - już połączony / połączenie udane
  • offline - połączenie nieudane

Wymagany jest Internet Explorer 3 lub nowszy


3.2 AutodialOnline


Powoduje, że modem automatycznie łączy się z domyślnym połączeniem internetowym, jeśli system nie jest jeszcze podłączony. Jeśli w systemie brak skonfigurowanej opcji automatycznego łączenia z internetem, użytkownik zostanie zapytany o zgodę na takie połączenie.

Zwracane wartości:

  • online - już połączony / połączenie udane
  • offline - połączenie nieudane

Wymagany jest Internet Explorer 4 lub nowszy


3.3 AutodialUnattended


Powoduje, że modem automatycznie łączy się z domyślnym połączeniem internetowym, jeśli system nie jest jeszcze podłączony. Użytkownik nie będzie pytany o zgodę na połączenie.

Zwracane wartości:

  • online - już połączony / połączenie udane
  • offline - połączenie nieudane

Wymagany jest Internet Explorer 4 lub nowszy


3.4 AutodialHangup


Rozłącza automatyczne połączenie dial-up.

Zwracane wartości:

  • success - rozłączanie udane
  • failure - rozłączanie nieudane

Wymagany jest Internet Explorer 4 lub nowszy


3.5 GetConnectedState


Sprawdza, czy system jest podłączony do internetu.

Zwracane wartości:

  • online - system jest online
  • offline - system jest offline

Wymagany jest Internet Explorer 4 lub nowszy

4. Autorzy

Napisał: Amir Szekely aka KiCHiK

Pomoc napisał: Joost Verburg